Microsoft Access Club >ADOX入門講座 >このページ >次頁 < 前項  サイト内検索
 

ADOXを用いてクエリ名を取得する : ADOX入門講座



CatalogオブジェクトのViewコレクションには、 パラメータを含まない選択クエリが管理されています。また。Procedureコレクションには、パラメータを含む選択クエリやアクションクエリが管理されています。これらは。それぞれのオブジェクトにあるNameプロパティの値によってクエリ名を参照することができます。

留意点
  • クエリ名の取得は参照のみ可能です。クエリ名の変更等はできません。

ADOXを用いてクエリ名を取得する

このプロシージャを実行すると、メッセージボックスにクエリ名の一覧が表示されます。クエリ毎のデータバックアップや削除などでクエリ名を指定する際に利用されるといいでしょう。

Sub MyQueryName()

On Error GoTo エラー

    Dim Cat As ADOX.Catalog
    Dim viw As ADOX.View
    Dim pcd As ADOX.Procedure
    Dim strmsg As String
    
    Set Cat = New ADOX.Catalog
    Cat.ActiveConnection = CurrentProject.Connection 'カレントデータベースに接続
    
    For Each viw In Cat.Views ' --- A
        strmsg = strmsg & vbNewLine & "・" & viw.Name
    Next viw
    
    For Each pcd In Cat.Procedures ' --- B
        If Left(pcd.Name, 1) <> "~" Then ' --- C
            strmsg = strmsg & vbNewLine & "・" & pcd.Name
        End If
    Next pcd
    
    MsgBox strmsg
    Set Cat = Nothing
    
    Exit Sub
    
エラー:
    
    MsgBox Err.Number & vbNewLine & Err.Description, vbCritical
    Exit Sub

End Sub
解説
  1. ViewsオブジェクトのNameプロパティを用いて、パラメータを含まない選択クエリー名を取得します。
  2. ProceduresオブジェクトのNameプロパティを用いて、パラメータを含む選択クエリーとアクションクエリ名を取得します。
  3. チルダ(~)から始まるクエリ名を除外しています。

  • チルダ(~)を含むクエリを含めた場合。

2005/08/31

ページの先頭へ 前ページへ戻る


ADOXを用いてクエリ名を取得する : ADOX入門講座


 

-Microsoft Access Club-

アメリカ合衆国の大手データセンターのアダルト対応可能なリーズナブル価格設定の専用・共有レンタルサーバーをご提供しています。
アメリカ合衆国の大手データセンターにサーバー機器を設置。
アダルト対応可能な専用・共有レンタルサーバーを提供。